Examples

A cube-frame corner: three 3/4-inch rods along +X, +Y and +Z.

Source: examples/corner_three_way.scad
// A cube-frame corner: three 3/4-inch rods along +X, +Y and +Z.
use <../rod_connectors.scad>

$fn = $preview ? 32 : 96;

d = 19.05;
rod_connector([
  rod([1, 0, 0], diameter=d, depth=35),
  rod([0, 1, 0], diameter=d, depth=35),
  rod([0, 0, 1], diameter=d, depth=35),
]);

examples/corner_three_way.scad on GitHub

Five 1-inch rods: four legs splayed down and out, one post straight up.

The connector this library started from.

Source: examples/hub_five_way.scad
// Five 1-inch rods: four legs splayed down and out, one post straight up.
// The connector this library started from.
use <../rod_connectors.scad>

$fn = $preview ? 32 : 96;

leg = function(x, y) rod([x, y, -0.8]);

rod_connector([
  leg(1, 0),
  leg(0, 1),
  leg(-1, 0),
  leg(0, -1),
  rod([0, 0, 1]),
]);

examples/hub_five_way.scad on GitHub

One hub, three rod sizes: a 1-inch post held by a set screw, a 1/2-inch arm that clamps with a slot, and a 10 mm stay at an angle.

Source: examples/mixed_rods.scad
// One hub, three rod sizes: a 1-inch post held by a set screw, a 1/2-inch
// arm that clamps with a slot, and a 10 mm stay at an angle.
use <../rod_connectors.scad>

$fn = $preview ? 32 : 96;

rod_connector([
  rod([0, 0, 1], diameter=25.4, screw=4),
  rod([1, 0, 0], diameter=12.7, depth=30, wall=4, slot=2, feature_angle=90),
  rod([-1, 1, -1], diameter=10, depth=25, wall=3),
]);

examples/mixed_rods.scad on GitHub

A tripod head: three legs spread 120 degrees apart, each 25 degrees out from straight down, and a post straight up.

Directions by angle with dir_spherical(theta, phi): theta from +Z, phi around from +X.

Source: examples/tripod_spherical.scad
// A tripod head: three legs spread 120 degrees apart, each 25 degrees out
// from straight down, and a post straight up. Directions by angle with
// dir_spherical(theta, phi): theta from +Z, phi around from +X.
use <../rod_connectors.scad>

$fn = $preview ? 32 : 96;

splay = 25;
rod_connector([
  for (phi = [0, 120, 240]) rod(dir_spherical(180 - splay, phi), diameter=16, depth=40, wall=4),
  rod(dir_spherical(0, 0), diameter=16, depth=30, wall=4, screw=4),
]);

examples/tripod_spherical.scad on GitHub


This site uses Just the Docs, a documentation theme for Jekyll.